<% Option Explicit %>
<!--#include file="common.inc" -->
<%
'****************************************************************************************
'**  Copyright Notice    
'**
'**  Web Wiz Guide Internet Search Engine
'**                                                              
'**  Copyright 2001-2002 Bruce Corkhill All Rights Reserved.                                
'**
'**  This program is free software; you can modify (at your own risk) any part of it 
'**  under the terms of the License that accompanies this software and use it both 
'**  privately and commercially.
'**
'**  All copyright notices must remain in tacked in the scripts and the 
'**  outputted HTML.
'**
'**  You may use parts of this program in your own private work, but you may NOT
'**  redistribute, repackage, or sell the whole or any part of this program even 
'**  if it is modified or reverse engineered in whole or in part without express 
'**  permission from the author.
'**
'**  You may not pass the whole or any part of this application off as your own work.
'**   
'**  All links to Web Wiz Guide and powered by logo's must remain unchanged and in place
'**  and must remain visible when the pages are viewed unless permission is first granted
'**  by the copyright holder.
'**
'**  This program is distributed in the hope that it will be useful,
'**  but WITHOUT ANY WARRANTY; without even the implied warranty of
'**  MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE OR ANY OTHER 
'**  WARRANTIES WHETHER EXPRESSED OR IMPLIED.
'**
'**  You should have received a copy of the License along with this program; 
'**  if not, write to:- Web Wiz Guide, PO Box 4982, Bournemouth, BH8 8XP, United Kingdom.
'**    
'**
'**  No official support is available for this program but you may post support questions at: -
'**  http://www.webwizguide.info/forum
'**
'**  Support questions are NOT answered by e-mail ever!
'**
'**  For correspondence or non support questions contact: -
'**  info@webwizguide.com
'**
'**  or at: -
'**
'**  Web Wiz Guide, PO Box 4982, Bournemouth, BH8 8XP, United Kingdom
'**
'****************************************************************************************


Response.Buffer = True 

'Dimension variables
Dim rsSearchResults 		'database Recordset Variable
Dim intRecordPositionPageNum 	'Holds the record position
Dim intRecordLoopCounter 	'Loop counter for displaying the database records
Dim lngTotalRecordsFound 	'Holds the total number of records in the database
Dim lngTotalNumPages 		'holds the total number of pages in the database
Dim intLinkPageNum 		'Holds the page number to be linked to
Dim intLoopCounter		'Holds the loop counter number
Dim sarySearchWord	 	'Holds the keywords for the URL
Dim strSearchKeywords		'Holds the keywords to be searched
Dim intSQLLoopCounter		'Loop counter for the loop for the sql query
Dim intSearchWordLength		'Holds the length of the word to be searched
Dim blnSearchWordLenthOK	'Boolean set to false if the search word length is not OK
Dim intRecordDisplayFrom	'Holds the number of the search result that the page is displayed from
Dim intRecordDisplayedTo	'Holds the number of the search result that the page is displayed to


'If this is the first time the page is displayed then the page position is set to page 1
If Request.QueryString("PagePosition") = "" Then
	intRecordPositionPageNum = 1

'Else the page has been displayed before so the page postion is set to the Record Position number
Else
	intRecordPositionPageNum = CInt(Request.QueryString("PagePosition"))
End If	


'Read in all the search words into one variable
strSearchKeywords = Trim(Request.QueryString("search"))

'If the use has not entered a value then let the search words variable contain a space (chr10)
If strSearchKeywords = "" Then strSearchKeywords = chr(10)

'Replace any less than or greater than signs with the HTML equivalent (stops people entering HTML tags)
strSearchKeywords = Replace(strSearchKeywords, "<", "&lt;")
strSearchKeywords = Replace(strSearchKeywords, ">", "&gt;")
strSearchKeywords = Replace(strSearchKeywords, "'", "''")

'Read in the search words to be searched
sarySearchWord = Split(Trim(strSearchKeywords), " ")

'Return the tow '' back to one' for displaying on the screen
strSearchKeywords = Replace(strSearchKeywords, "''", "'")


'Initalise the word search length variable
blnSearchWordLenthOK = True

'Loop round to check that each word to be searched has more than the minimum word length to be searched
For intLoopCounter = 0 To UBound(sarySearchWord)
	
	'Initialise the intSearchWordLength variable with the length of the word to be searched
	intSearchWordLength = Len(sarySearchWord(intLoopCounter))
	
	'If the word length to be searched is less than or equal to min word length then set the blnWordLegthOK to false
	If intSearchWordLength <= intMinuiumSearchWordLength Then 
		blnSearchWordLenthOK = False		
	End If
Next


'Create a recordset object
Set rsSearchResults = Server.CreateObject("ADODB.Recordset")

	
'Initalise the strSQL variable with an SQL statement to query the database
strSQL = "SELECT tblWebsites.* FROM tblWebsites "
		
'Get the mode to decide how we are going to buid the SQL Query
Select Case Request.QueryString("mode")

	'If the user has selected to search any words then intalise the strSQL statement to search for any words in the database
	Case "anywords"

		'Search for the first search word in the URL titles
		strSQL = strSQL & "WHERE Title LIKE '%" & sarySearchWord(0) & "%'"
	
		'Loop to search for each search word entered by the user
		For intSQLLoopCounter = 0 To UBound(sarySearchWord)
			strSQL = strSQL & " OR Title LIKE '%" & sarySearchWord(intSQLLoopCounter) & "%'"
			strSQL = strSQL & " OR Keywords LIKE '%" & sarySearchWord(intSQLLoopCounter) & "%'" 
			strSQL = strSQL & " OR Description LIKE '%" & sarySearchWord(intSQLLoopCounter) & "%'"
		Next
		
		'Order the search results by the number of click through hits decending (most popular sites first)
		strSQL = strSQL & " ORDER By Rating DESC, No_of_ratings DESC, Hits DESC;"


	'If the user has selected to search for all words then intalise the strSQL statement to search for entries containing all the search words
	Case "allwords"
	
		'Search for the first word in the URL titles
		strSQL = strSQL & "WHERE (Title LIKE '%" & sarySearchWord(0) & "%'"
		
		'Loop to search the URL titles for each word to be searched
		For intSQLLoopCounter = 1 To UBound(sarySearchWord)
			strSQL = strSQL & " AND Title LIKE '%" & sarySearchWord(intSQLLoopCounter) & "%'"
		Next
		
		'OR if the search words are in the keywords	
		strSQL = strSQL & ") OR (Keywords LIKE '%" & sarySearchWord(0) & "%'"
		
		'Loop to search the URL keywords for each word to be searched
		For intSQLLoopCounter = 1 To UBound(sarySearchWord)
			strSQL = strSQL & " AND Keywords LIKE '%" & sarySearchWord(intSQLLoopCounter) & "%'"
		Next
		
		'Or if the search words are in the title	
		strSQL = strSQL & ") OR (Description LIKE '%" & sarySearchWord(0) & "%'"
		
		'Loop to search the URL description for each word to be searched
		For intSQLLoopCounter = 1 To UBound(sarySearchWord)
			strSQL = strSQL & " AND Description LIKE '%" & sarySearchWord(intSQLLoopCounter) & "%'"
		Next
		
		'Order the search results by the number of click through hits decending (most popular sites first)
		strSQL = strSQL & ") ORDER By Rating DESC, No_of_ratings DESC, Hits DESC;"


	'If the user has selected to see newly enetred URL's then order the search results by date decending
	Case "new"
		'Initalise the strSQL variable with an SQL statement to query the database
		strSQL = "SELECT TOP " & intRecordsPerPage & " tblWebsites.* FROM tblWebsites"
		strSQL = strSQL & " ORDER By SiteIDNo DESC;"
End Select

'Query the database with the strSQL statement
rsSearchResults.Open strSQL, strCon, 3

'Count the number of records found
lngTotalRecordsFound = CLng(rsSearchResults.RecordCount)	

'If this is a random URL then strip all the other URL's and only leave one remaining URL
If Request.QueryString("submit") = "Random Search" and NOT rsSearchResults.EOF Then 
	
	'Randomise system timer
	Randomize Timer
	
	'Move to a random record in the recordset
	rsSearchResults.Move CLng(RND * lngTotalRecordsFound) - 0.5

	'Filter out all the other records
	rsSearchResults.Filter = "SiteIDNo =" & rsSearchResults("SiteIDNO")

Else
	'Set the number of records to display on each page by the constant set at the top of the script
	rsSearchResults.PageSize = intRecordsPerPage
	
	'Get the page number record poistion to display from
	IF NOT rsSearchResults.EOF Then rsSearchResults.AbsolutePage = intRecordPositionPageNum
	
	'Count the number of pages the search results will be displayed on calculated by the PageSize attribute set above
	lngTotalNumPages = CLng(rsSearchResults.PageCount)
	
	
	'Calculate the the record number displayed from and to on the page showing
	intRecordDisplayFrom = (intRecordPositionPageNum - 1) * intRecordsPerPage + 1
	intRecordDisplayedTo = (intRecordPositionPageNum - 1) * intRecordsPerPage + intRecordsPerPage
	If intRecordDisplayedTo > lngTotalRecordsFound Then intRecordDisplayedTo = lngTotalRecordsFound

End If
%>
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1"> <title>Search 
the Internet: <% = strSearchKeywords %></title> <!-- The Web Wiz Guide Internet Search Engine is written by Bruce Corkhill Š2001
   	  If you want your own Internet Search Engine then goto http://www.webwizguide.info --


<!-- Check the from is filled in correctly before submitting --> <SCRIPT  language="JavaScript">
<!--
<!-- Hide from older browsers...
//Check the enquiry form is filled in correctly
function CheckForm () { 
		
	//If there is aproblem with the form then display an error
	if (document.frmInterSearch.search.value == "") {
		msg = "_________________________________________________________________\n\n";
		msg += "Your search has not been submitted because there are problem(s) with the form.\n";
		msg += "Please correct the problem(s) and re-submit the form.\n";
		msg += "_________________________________________________________________\n\n";
		msg += "\n\tPlease enter at least one keyword to search for."
		
		alert(msg + "\n\n");
		
		return false;
	}
	
	return true;
}

//Function to open pop up window
function openWin(theURL,winName,features) {
  	window.open(theURL,winName,'toolbar=0,location=0,status=0,menubar=0,scrollbars=0,resizable=0,width=350,height=310');
}
// -->

function MM_openBrWindow(theURL,winName,features) { //v2.0
  window.open(theURL,winName,features);
}
//-->
</script> <style type="text/css">
<!--
.text {font-family: <% = strTextType %>; font-size: <% = intTextSize %>px; color: <% = strTextColour %>}
.bold {font-family: <% = strTextType %>; font-size: <% = intTextSize %>px; color: <% = strTextColour %>; font-weight: bold;}
.italic {font-family: <% = strTextType %>; font-size: <% = intTextSize - 1 %>px; color: #009900; font-style: italic;}
.heading {font-family: <% = strTextType %>; font-size: 24px; color: <% = strTextColour %>; font-weight: bold;}
a {font-family: <% = strTextType %>; font-size: <% = intTextSize %>px; color: <% = strLinkColour %>}
a:hover {font-family: <% = strTextType %>; font-size: <% = intTextSize %>px; color: <% = strHoverLinkColour %>}
a:visited {font-family: <% = strTextType %>; font-size: <% = intTextSize %>px; color: <% = strVisitedLinkColour %>}
a:visited:hover {font-family: <% = strTextType %>; font-size: <% = intTextSize %>px; color: <% = strHoverLinkColour %>}

-->
</style> 
</head>
<body bgcolor="<% = strBgColour %>" text="<% = strTextColour %>" leftmargin="0" topmargin="0">
<div align="center" class="heading"> <TABLE WIDTH="98%" BORDER="0" CELLSPACING="0" CELLPADDING="0" HEIGHT="62"> 
<TR> <TD HEIGHT="54"><IMG SRC="../new-img/best-2k3_01.gif" WIDTH="164" HEIGHT="99"><IMG SRC="../new-img/best-2k3_02.gif" WIDTH="188" HEIGHT="99"><IMG SRC="../new-img/best-2k3_03.gif" WIDTH="147" HEIGHT="99"><IMG SRC="../new-img/best-2k3_04.gif" WIDTH="142" HEIGHT="99"><IMG SRC="../new-img/best-2k3_05.gif" WIDTH="138" HEIGHT="99"></TD></TR> 
</TABLE><TABLE CELLSPACING=0 CELLPADDING=0 WIDTH="78%" BORDER=0 HEIGHT="8"> <TBODY> 
<TR> <TD COLSPAN=2 HEIGHT=7><SMALL><SMALL><BR> </SMALL></SMALL></TD><TD VALIGN=bottom ALIGN=right WIDTH="90%" ROWSPAN=2><FONT 
            STYLE="FONT-SIZE: 10px" FACE=verdana SIZE=-2> </FONT></TD></TR> <TR> 
<TD noWrap BGCOLOR=#B3D98C HEIGHT=15 ROWSPAN=2> <TABLE CELLSPACING=0 CELLPADDING=0 WIDTH=135 BORDER=0> 
<TBODY> <TR> <TD WIDTH=135></TD></TR> </TBODY> </TABLE><FONT FACE=verdana 
            COLOR=white SIZE=-2>&nbsp;&nbsp;<B><FONT SIZE="1" FACE="Verdana, Arial, Helvetica, sans-serif"><B><FONT COLOR="#003300">Net 
Search Engine</FONT></B></FONT></B></FONT></TD><TD VALIGN=top BGCOLOR=#B3D98C><IMG ID=cti2 HEIGHT=15 ALT="" 
            SRC="../new-img/tr14x15_1.gif" WIDTH=14></TD></TR> <TR> <TD BGCOLOR=#B3D98C COLSPAN=2 HEIGHT="5"> 
<TABLE CELLSPACING=0 CELLPADDING=0 BORDER=0> <TBODY> <TR> <TD HEIGHT=3></TD></TR> 
</TBODY> </TABLE></TD></TR> </TBODY> </TABLE><TABLE WIDTH="79%" BORDER="0" CELLSPACING="0" CELLPADDING="0"> 
<TR> <TD COLSPAN="2"> <DIV ALIGN="center"><FONT SIZE="1" FACE="Verdana, Arial, Helvetica, sans-serif" COLOR="#FF0000">| 
<A HREF="http://www.bestwebonline.com/index.html">Home</A> | | <A HREF="http://www.bestwebonline.com/aboutus.html">About 
Us</A> | | <A HREF="http://www.bestwebonline.com/services.htm">Services</A> | 
| <A HREF="http://www.bestwebonline.com/site_search.asp">Site Search</A> | | <A HREF="http://www.bestwebonline.com/business.html">Queries</A> 
| | <A HREF="http://www.bestwebonline.com/Faq.html">Faqs</A> | | <A HREF="#" ONCLICK="MM_openBrWindow('http://www.bestwebonline.com/bestmail.asp','','width=500,height=330')">Send 
Email</A> | | <A HREF="http://www.bestwebonline.com/contactus.html">Contact Us</A> 
|</FONT><FONT SIZE="1" FACE="Verdana, Arial, Helvetica, sans-serif" COLOR="#006600"><BR> 
| <A HREF="http://www.bestwebonline.com/domain_checker/domain_checker.asp" TARGET="_self"><B>Check 
Domain Name</B></A> | <A HREF="http://www.bestwebonline.com/whois/whois.asp" TARGET="_self"><B>Who 
is Lookup </B></A>| <A HREF="http://www.bestwebonline.com/bestint_engine/default.asp" TARGET="_self"><B>Net 
Search Engine</B></A> | <A HREF="http://www.bestwebonline.com/bestint_engine/add_url_form.asp" TARGET="_self"><B>Add 
URL</B></A> | <A HREF="default.asp?mode=new"><B>Recently Submitted Web Sites</B></A> 
|</FONT></DIV></TD></TR> </TABLE></div><form method="get" name="frmInterSearch" action="default.asp" onSubmit="return CheckForm();"> 
<table cellpadding="0" cellspacing="0" width="70%" align="center" style="BORDER-BOTTOM: black 1px solid; BORDER-LEFT: black 1px solid; BORDER-RIGHT: black 1px solid; BORDER-TOP: black 1px solid" > 
<tr> <td height="61" width="77" align="right" rowspan="3" bgcolor="#CEE7B6"><DIV ALIGN="CENTER"><IMG SRC="../new-img/comp159.gif" WIDTH="32" HEIGHT="32" BORDER="1"></DIV></td><td height="61" width="10" align="right" rowspan="3" bgcolor="#CEE7B6">&nbsp;</td><td class="text" height="2" width="467" valign="bottom" bgcolor="#CEE7B6"><font size="2" face="Verdana, Arial, Helvetica, sans-serif" color="#FFCC00"> 
<b><FONT COLOR="#003300" SIZE="1">&nbsp; Web Page Search : </FONT></b></font></td></tr> 
<tr> <td class="normal" height="2" width="467" bgcolor="#CEE7B6"> <input type="TEXT" name="search" maxlength="50" size="35" value="<% =Request.QueryString("search") %>" style="background-color:#c6df9a"> 
<input type="submit" value="Search " name="submit" style="background-color:#336600; font-face:arial; font-size:12; font-weight:bold; color:#c6df9a"> 
<input type="submit" name="submit" value="Random Search" style="background-color:#336600; font-face:arial; font-size:12; font-weight:bold; color:#c6df9a"> 
</td></tr> <tr> <td class="text" height="7" width="467" valign="top" bgcolor="#CEE7B6"><font size="2" face="Verdana, Arial, Helvetica, sans-serif" color="#c6df9a"> 
<FONT COLOR="#003300">&nbsp;Search On : <input type="radio" name="mode" value="allwords" CHECKED> 
All Words <input type="radio" name="mode" value="anywords"> Any Words </FONT></font></td></tr> 
</table><br> <%

If NOT Request.QueryString("mode") = "" Then 
	'Display the HTML table with the results status of the search or what type of search it is
	Response.Write vbCrLf & "     <table width=""98%"" border=""0"" cellspacing=""0"" cellpadding=""1"" align=""center"" bgcolor=""" & strTableBorderColour & """>"
	Response.Write vbCrLf & "      <tr>"
	Response.Write vbCrLf & " 	<td>"
	Response.Write vbCrLf & "	<table width=""100%"" border=""0"" cellspacing=""0"" cellpadding=""2"" align=""center"" bgcolor=""" & strTableColour & """>"
	Response.Write vbCrLf & " 	  <tr>"
	
	'Display that the URL is randomly generated	
	If Request.QueryString("submit") = "Random Search" Then
		Response.Write vbCrLf & " 	    <td  class=""text""> Random Search for <span class=""bold"">" & strSearchKeywords & "</span>.</td>"
		
	'Display that we are showing a page of the latest URL's indexed
	ElseIf Request.QueryString("mode") = "new" Then
		Response.Write vbCrLf & " 	    <td class=""text""> The " & intRecordsPerPage & " latest URL's Indexed.</td>"  
		 
	'Display that one of the words entered was to short
	ElseIf	blnSearchWordLenthOK = False Then
		Response.Write vbCrLf & " 	    <td class=""text""> Searched the web for <span class=""bold"">" & strSearchKeywords & "</span>. &nbsp;&nbsp;&nbsp;One of the words searched is to short.</td>"   
	
	'Display that there where no matching records found
	ElseIf rsSearchResults.EOF Then 
		Response.Write vbCrLf & " 	    <td class=""text""> Searched the web for <span class=""bold"">" & strSearchKeywords & "</span>. &nbsp;&nbsp;&nbsp;Sorry, no results found.</td>"   
	
	'Else Search went OK so display how many records found
	Else	
		Response.Write vbCrLf & " 	    <td class=""text""> Searched the web for <span class=""bold"">" & strSearchKeywords & "</span>. &nbsp;&nbsp;&nbsp;Displaying Results " & intRecordDisplayFrom & " - " & intRecordDisplayedTo & " of " & lngTotalRecordsFound & ".</td>"	    
	End If
			
	'Close the HTML table with the search status
	Response.Write vbCrLf & "	  </tr>"
	Response.Write vbCrLf & "	</table>"
	Response.Write vbCrLf & "	</td>"
	Response.Write vbCrLf & "      </tr>"
	Response.Write vbCrLf & "     </table>"


	'Display the various results
	
	'HTML table to display the search results or an error if there are no results
	Response.Write vbCrLf & "	<br>" & vbCrLf 
	Response.Write vbCrLf & "	<table width=""95%"" border=""0"" cellspacing=""1"" cellpadding=""1"" align=""center"">"
	Response.Write vbCrLf & "	 <tr>" 
	Response.Write vbCrLf & "	  <td class=""text"">"   
	
	'Display error message if one of the words is to short
	If blnSearchWordLenthOK = False And NOT Request.QueryString("mode") = "new" Then
	
		'Write HTML displaying the error
		Response.Write vbCrLf & "	   Your Search - <span class=""bold"">" & strSearchKeywords & "</span> - Contained a word with " & intMinuiumSearchWordLength & " letters or less, this is to short to search."
	   	Response.Write vbCrLf & "	   <br><br>"
	   	Response.Write vbCrLf & "	   Suggestions:"
	   	Response.Write vbCrLf & "	   <br>"
	   	Response.Write vbCrLf & "	   <ul><li>Try longer keywords.<li>Make sure all words are spelled correctly.<li>Try different keywords.<li>Try more general keywords.</ul>"
	   	
	'If no search results found then show an error message
	ElseIf rsSearchResults.EOF Then
	
		'Write HTML displaying the error
		Response.Write vbCrLf & "	   Your Search - <span class=""bold"">" & strSearchKeywords & "</span> - did not match any documents."
	   	Response.Write vbCrLf & "	   <br><br>"
	   	Response.Write vbCrLf & "	   Suggestions:"
	   	Response.Write vbCrLf & "	   <br>"
	   	Response.Write vbCrLf & "	   <ul><li>Make sure all words are spelled correctly.<li>Try different keywords.<li>Try more general keywords.<li>Try fewer keywords.</ul>"
	   	
	Else
		'For....Next Loop to display the results from the database
		For intRecordLoopCounter = 1 to intRecordsPerPage
		
			'If there are no records left to display then exit loop
			If rsSearchResults.EOF Then Exit For					
		      	
		      	'Display the details of the URLs found		
	   		Response.Write vbCrLf & "	   <a href=""get_url.asp?SiteID=" & CInt(rsSearchResults("SiteIDNo")) & """ target=""_blank"">" & rsSearchResults("Title") & "</a>"
	   		Response.Write vbCrLf & "	   <br>"
	   		Response.Write vbCrLf & "	   " & rsSearchResults("Description")
	   		Response.Write vbCrLf & "	   <br>"
	   		Response.Write vbCrLf & "	   <span class=""italic""><img src=""images/" & CInt(rsSearchResults("Rating")) & "_star_rating.gif"" width=""66"" height=""14"" alt=""" & CInt(rsSearchResults("Rating")) & " star rating""> Average rating based on " & CLng(rsSearchResults("No_of_ratings")) & " votes&nbsp;&nbsp;-&nbsp;&nbsp;<a href=""JavaScript:openWin('rate_link.asp?SiteID=" & rsSearchResults("SiteIDNo") & "','rate_site')"" style=""font-size:" & intTextSize-1 & "; font-style: italic;"">Rate Link</a>&nbsp;&nbsp;-&nbsp;&nbsp;Hits&nbsp;" & CInt(rsSearchResults("Hits")) & "&nbsp;&nbsp;-&nbsp;&nbsp;" & Replace(rsSearchResults("URL"), "http://", "") & "</span>"
	   		Response.Write vbCrLf & "	   <br><br>"
	   	
			'Move to the next record in the database
			rsSearchResults.MoveNext
		
		'Loop back round   	
		Next
	 End If
	
	'Close the HTML table displaying the results
	Response.Write vbCrLf & "	    </td>"
	Response.Write vbCrLf & "	  </tr>"
	Response.Write vbCrLf & "	</table>"
	
	 
	'If there are more pages to display then add a title to the other pages
	If intRecordPositionPageNum > 1 OR NOT rsSearchResults.EOF AND blnSearchWordLenthOK = True Then
	
		 'Display an HTML table with links to the other search results
		Response.Write vbCrLf & "	<table width=""100%"" border=""0"" cellspacing=""0"" cellpadding=""0"" align=""center"">"
		Response.Write vbCrLf & " 	  <tr>"
		Response.Write vbCrLf & " 	    <td>"
		Response.Write vbCrLf & "		<table width=""100%"" border=""0"" cellpadding=""0"" cellspacing=""0"">"
		Response.Write vbCrLf & "		  <tr>"
		Response.Write vbCrLf & "		    <td width=""50%"" align=""center""  class=""text"">"
		
		'If there are more pages to display then add a title to the other pages
		If intRecordPositionPageNum > 1 or NOT rsSearchResults.EOF Then
			Response.Write vbCrLf & "		Results Page:&nbsp;&nbsp;"
		End If
		
		'If the page number is higher than page 1 then display a back link    	
		If intRecordPositionPageNum > 1 Then 
			Response.Write vbCrLf & "		 <a href=""default.asp?PagePosition=" &  intRecordPositionPageNum - 1  & "&search=" & Server.URLEncode(strSearchKeywords) & "&mode=" & Request.QueryString("mode") &""" target=""_self"">&lt;&lt;&nbsp;Prev</a>&nbsp; "   	     	
		End If     	
		
		
		'If there are more pages to display then display links to all the search results pages
		If intRecordPositionPageNum > 1 or NOT rsSearchResults.EOF Then 
			
			'Loop to diplay a hyper-link to each page in the search results    	
			For intLinkPageNum = 1 to lngTotalNumPages		
				
				'If the page to be linked to is the page displayed then don't make it a hyper-link
				If intLinkPageNum = intRecordPositionPageNum Then
					Response.Write vbCrLf & "		     " & intLinkPageNum
				Else
				
					Response.Write vbCrLf & "		     &nbsp;<a href=""default.asp?PagePosition=" &  intLinkPageNum  & "&search=" & Server.URLEncode(strSearchKeywords) & "&mode=" & Request.QueryString("mode") & """ target=""_self"">" & intLinkPageNum & "</a>&nbsp; "			
				End If
			Next
		End If
		
		
		'If it is Not the End of the search results than display a next link     	
		If NOT rsSearchResults.EOF then   	
			Response.Write vbCrLf & "		&nbsp;<a href=""default.asp?PagePosition=" &  intRecordPositionPageNum + 1  & "&search=" & Server.URLEncode(strSearchKeywords) & "&mode=" & Request.QueryString("mode") & """ target=""_self"">Next&nbsp;&gt;&gt;</a>"	   	
		End If      	
		
		
		'Finsh HTML the table      	
		Response.Write vbCrLf & "		    </td>"      	
		Response.Write vbCrLf & "		  </tr>"
		Response.Write vbCrLf & "		</table>"		
		Response.Write vbCrLf & "	    </td>"
		Response.Write vbCrLf & "	  </tr>"
		Response.Write vbCrLf & "	</table>"
		Response.Write vbCrLf & "	<br>"
	 
	End If 
End If


'Close Server Objects 
Set rsSearchResults = Nothing
Set strCon = Nothing
Set adoCon = Nothing
%> <table width="98%" border="0" cellspacing="0" cellpadding="1" align="center" bgcolor="<% = strTableBorderColour %>"> 
<tr> <td> <table width="100%" border="0" cellspacing="0" cellpadding="0" bgcolor="<% = strTableColour %>"> 
<tr> <td> <table width="100%" border="0" cellspacing="0" cellpadding="2" align="center"> 
<tr> <td> <div align="center"><a href="add_url_form.asp"><font size="2" face="Verdana, Arial, Helvetica, sans-serif">Submit 
Web Site</font></a> <font size="2" face="Verdana, Arial, Helvetica, sans-serif">&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;<a href="default.asp?mode=new">Recently 
Submitted Web Sites</a></font></div></td></tr> </table></td></tr> </table></td></tr> 
</table></form><div align="center"> </div>
   </body>
</html>